c Hindi Keyboard Version 2.0
c by Mihcael Colley
c To be used with the font DevanagariDelhiSSK
c This file may be disrtibuted freely as long as it is not modified
c © Michael Colley 1997

name "Hindi"
Bitmaps hindi1 hindi0
hotkey "^%H"
version 3.2

begin > use(Main)

store(HConsonant) 'µ·¼ÄÆÈÊÌÎÏÐÒÕÖØÙº¹¾¶¸½ÅÇËÍ»¿ÁÃ×ÀÂøùúûþÿüýbckW|Œ}~'
store(KRegular) 'kgjtdnpbmyrlvxshcqzKGJTDPBC'
store(HRegular) 'µ·¼ÄÆÈÊÌÎÏÐÒÕÖØÙº¹¾¶¸½ÅÇËÍ»'
store(KCerebral) 'ÄÆÈØÅÇ'
store(HCerebral) '¿ÁÃ×ÀÂ'
store(KDotUnder) 'µ¶·¼ËÏÁÂ'
store(HDotUnder) 'øùúûþÿüý'

store(KVowel) 'aiueo'
store(HVowel) '¥§©¯³'

store(NotConnected) 'µ·¼ÄÈÊÌÎÏÒÕÖØÙº¾¶¸ÅÇËÍ»×'
store(HConnecting) '@BFHKM[PQRSTUVDGACIJNOE\'

store(LeftR) 'µË'
store(RightR) '·¸º¼¾ÃÅÈÊÌÍÎÏÕ×'
store(LowR) '¶¹»½¿ÀÁÂÄÆÇÐÒÖØÙ'
store(Bindu) 'çèëì°³´à¨'
store(Chondrabindu) 'Þâãᥦ§©ª¯«'

group(Main) using keys

C ***CONSONANTS***
'w' > dk(1)
'f' > dk(2)
any(KRegular) > index(HRegular,1)
any(KCerebral) + 'w' > index(HCerebral,1)
any(KDotUnder) + 'f' > index(HDotUnder,1)

C ***KS LIGATURE***
'@' + 'Ø' + 'w' > 'W'
'W' + 'a' > 'WÞ' + dk(3)

C ***INDEPENDENT VOWELS***
any(KVowel) > index(HVowel,1)
'¥' + 'a' > '¦'
'§' + 'i' > '¨'
'©' + 'u' > 'ª'
'¯' + 'e' > '°'
'³' + 'o' >  '´'
'R' > '«'

C ***VOWEL SIGNS***
any(HConsonant) + 'a' > index(HConsonant,1) + dk(3)
dk(3) + 'a' > 'Þ'

any(HConsonant) + 'i' > 'ß' +  index(HConsonant,1)
'ß' + any(HConsonant) + 'i' > index(HConsonant,2) + 'à'

any(HConsonant) + 'u' > index(HConsonant,1) + 'á'
'á' + 'u' > 'â'

any(HConsonant) + 'R' > index(HConsonant,1) + 'ã'

any(HConsonant) + 'e' > index(HConsonant,1) + 'ç'
'ç' + 'e' > 'è'

any(HConsonant) + 'o' > index(HConsonant,1) + 'ë'
'ë' + 'o' > 'ì'

C ***ANUSVARA--NASALIZATION--DOT ABOVE***
any(HConsonant) + 'N' > index(HConsonant,1) + '¡'  
dk(3) + 'N' > '¡'
'ß' + any(HConsonant) + 'N' > 'ß' + index(HConsonant,2) + '¢'

any(Bindu) + 'N' > index(Bindu,1) + '¢'
any(Chondrabindu) + 'N' > index(Chondrabindu,1) + '¡'
 


C ***VISARG--APSIRATION---TWO DOTS BESIDE***
'H' > '£'

C ***VIRAM--ABSENSE OF VOWEL---LINE UNDER***
'A' > 'í'

C ***TT LIGATURE***
'Ä' + 't' > 'k'

C ***SUCCEEDING R***
any(LeftR) + 'r' > index(LeftR,1) + 'Œ' 
any(RightR) + 'r' > index(RightR,1) + '}'
any(LowR) + 'r' > index(LowR,1) + '~'

any(LeftR) + 'Œ' + 'i' > 'ß' + index(LeftR,1) + 'Œ'
'ß' + any(LeftR) + 'Œ' + 'i' > index(LeftR,2) + 'Œ' + 'à'

any(RightR) + '}' + 'i' > 'ß' + index(RightR,1) + '}'
'ß' + any(RightR) + '}' + 'i' > index(RightR,2) + '}' + 'à'

any(LowR) + '~' + 'i' > 'ß' + index(LowR,1) + '~'
'ß' + any(LowR) + '~' + 'i' > index(LowR,2) + '~' + 'à' 

C ***CONNECTING CONSONANTS***
any(NotConnected) + any(KRegular) > index(HConnecting,1) + index(HRegular,2)
'ß' + any(NotConnected) + any(KRegular) > 'ß' + index(NotConnected,2) + index(HRegular,3)
'Ã' + any(KRegular) > 'L' + index(HRegular,2)

C ***NGKA AND NGGA LIGATURES***
'¹' + 'k' > 'b'
'¹' + 'g' > 'c'

C ***PRECEDING R***
'Ð' + any(KRegular) > index(HRegular,2) + '|'
any(HRegular) + '|' + 'i' > 'ß' + index(HRegular,1) + '|' 
'ß' + any(HRegular) + '|' + 'i' > index(HRegular,2) + 'à' + '|'  
'ß' + 'Ð' + any(KRegular) > 'ß' + 'Ð' + index(HRegular,3)

any(KCerebral) + '|' + 'w' > index(HCerebral,1) + '|'